ansys 电磁单元例子：[1]plane53

1、最近打算把ans鲻戟缒男ys help中的vm例子做一遍，先从电磁单元开始吧。

最常用的是53单元了

第一个例子为载流导体的电磁力比较，分析了3种电磁的加载方法和比较。

2、apdl如下：

fini

/cle

!载流体的力计算

/filname,vm188,1

/title,Force Calculation on a Current Carrying Conductor

/prep7

et,1,53

et,2,9

emunits,mks

mp,murx,1,1

mp,murx,2,1

d=0.01

a=0.012

t=0.002

ob=0.04

x1=d/2-t/2

x2=d/2+t/2

gp=0.002

rect,0,ob,0,ob

rect,0,0.012,0,0.012

rect,x1,x2,0,a/2

rect,x1-gp,x2+gp,0,a/2+gp

aovlap,all

numcmp,all

aplot

asel,s,area,,1

aatt,2,,1

allsel

si_e=0.0002

esize,si_e

amesh,1

esize,si_e*2

amesh,4

esize,si_e*5

amesh,3

esize,si_e*10

amesh,2

lsel,s,ext

lsel,u,loc,x

lsel,u,loc,y

latt,1,,2

lmesh,all

allsel

fini

/sol

antype,static

esel,s,mat,,2

bfe,all,js,,,,1e6

nsle,s

bf,all,mvdi,1

nsel,inve

bf,all,mvdi,0

allsel

cnvtol,csg,1e-8

solve

fini

/post1

etable,fmagx,fmag,x

etab,fvwx,nmisc,3

ssum

*get,fxl,ssum,,item,fmagx

fxl=fxl*2

*get,fxvw,ssum,,item,fvwx

fxvw=fxvw*2

path,maxwell,4,,48

ppath,1,,0.012,0,0

ppath,2,,0.012,0.012,0

ppath,3,,0,0.012,0

ppath,4,,0,0,0

for2d

fxm=fx*2

*status,parm

/pbc,path,1

plf2d

*dim,label,char,3,2

*dim,value,,3,3

label(1,1)='F(lrnz)','F(maxw)','f(vw)'

label(1,2)='N/M','N/M','N/M'

*do,i,1,3,1

value(i,1)=-9.684e-3

*enddo

*vfill,value(1,2),data,fxl,fxm,fxvw

*do,i,1,3,1

value(i,3)=value(i,2)/value(1,1)

*enddo

/COM

/OUT,vm188,vrt

/COM,------------------- VM188 RESULTS COMPARISON --------------

/COM,

/COM, | TARGET | Mechanical APDL | RATIO

/COM,PLANE53

*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)

(1X,A8,A8,' ',F10.6,' ',F18.6,' ',1F15.3)

/OUT

3、结果如下

1.网格密度

2.磁力线分布

3、磁场分布

4.电磁力比较